Скетч данные с датчика давления и DHT22 (влажность и температура) передает в php скрипт, который находится на сервере, и который в свою очередь пишет эти данные в mySQL базу:
Код: Выделить всё
// Для Arduio 0023
//VCC на BMP085 подключаем к +3,3 V Arduino
//SDA на BMP085 подключаем к пин 20 (SDA) Arduino Mega 2560 (аналоговый пин 4 на Arduino Uno)
//SCL на BMP085 подключаем к пин 21 (SCL) Arduino Mega 2560 (аналоговый пин 5 на Arduino Uno)
//GND на BMP085 подключаем к GND Arduino
// DHT 22 (AM2302) подкючн цифровому пин 2
// 16.01.2014 проба заиси в базу двления, температуры и влажности
#include <DHT.h>
#include <Ethernet.h>
#include <SPI.h>
#include <string.h>
#include <Wire.h>
//************************ BMP085 ****************************
#define BMP085_ADDRESS 0x77 // I2C address of BMP085
const unsigned char OSS = 0; // Oversampling Setting
// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;
// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;
short temperature;
long pressure;
//************************************************************
byte mac[] = { 0x50, 0xA2, 0xDA, 0x00, 0x5C, 0xFB };
byte ip[] = { 192, 168, 8, 50 };
//IP адрес сервера который будет собирать статистику
byte server[] = { 192, 168, 8, 3 };
char buffer[256];
//EthernetClient client;
Client client(server, 80); // для компиллятра arduino 0023
//************************ DHT22 ****************************
//Контакт к которому подключен датчик температуры и влажности
#define DHTPIN 2
// Вы бираем сенсор который используется у вас, у меня DHT 22
//#define DHTTYPE DHT11 // для DHT 11
#define DHTTYPE DHT22 // для DHT 22 (AM2302)
DHT dht(DHTPIN, DHTTYPE);
//***********************************************************
void setup()
{
Ethernet.begin(mac, ip);
Serial.begin(9600);
dht.begin();
Wire.begin();
bmp085Calibration();
delay(1000);
}
void loop()
{
//************************ DHT22 ****************************
int h = dht.readHumidity();
int t = dht.readTemperature();
//***********************************************************
//************************ BMP085 ***************************
temperature = bmp085GetTemperature(bmp085ReadUT());
pressure = bmp085GetPressure(bmp085ReadUP());
int s = pressure/133.3;
int p = s + 17;// 17 - коэффициент учитывающий высоту над уровне мморя
//***********************************************************
Serial.print("Humidity: ");
Serial.print(h);
Serial.print(" %\t");
Serial.print("Temperature: ");
Serial.print(t);
Serial.println(" *C");
Serial.print("Pressure: ");
Serial.print(p);
Serial.println(" mmgH");
String msg = "GET /dhts.php?h="+ String(t) + "&t="+String(30);
String msg1 = "GET /dhts.php?h="+ String(h) + "&t="+String(31);
String msg2 = "GET /dhts.php?h="+ String(p) + "&t="+String(32);
// Для отладки включим отправку данных в COM порт
//Serial.println(msg);
//Serial.println(msg1);
//Serial.println(msg2);
client.connect(); // для компиллятра arduino 0023
//EthernetClient connect();
client.println(msg);
client.stop();
delay (500);
client.connect(); // для компиллятра arduino 0023
//EthernetClient connect(); // для компиллятра arduino 1.0
client.println(msg1);
client.stop();
delay (500);
//EthernetClient connect(); // для компиллятра arduino 1.0
client.connect(); // для компиллятра arduino 0023
client.println(msg2);
client.stop();
//Данные будут отправляться каждые 5 минут.
delay (300000);
//delay (10000);
}
// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
ac1 = bmp085ReadInt(0xAA);
ac2 = bmp085ReadInt(0xAC);
ac3 = bmp085ReadInt(0xAE);
ac4 = bmp085ReadInt(0xB0);
ac5 = bmp085ReadInt(0xB2);
ac6 = bmp085ReadInt(0xB4);
b1 = bmp085ReadInt(0xB6);
b2 = bmp085ReadInt(0xB8);
mb = bmp085ReadInt(0xBA);
mc = bmp085ReadInt(0xBC);
md = bmp085ReadInt(0xBE);
}
// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(unsigned int ut)
{
long x1, x2;
x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
x2 = ((long)mc << 11)/(x1 + md);
b5 = x1 + x2;
return ((b5 + 8)>>4);
}
// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
long x1, x2, x3, b3, b6, p;
unsigned long b4, b7;
b6 = b5 - 4000;
// Calculate B3
x1 = (b2 * (b6 * b6)>>12)>>11;
x2 = (ac2 * b6)>>11;
x3 = x1 + x2;
b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
// Calculate B4
x1 = (ac3 * b6)>>13;
x2 = (b1 * ((b6 * b6)>>12))>>16;
x3 = ((x1 + x2) + 2)>>2;
b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
b7 = ((unsigned long)(up - b3) * (50000>>OSS));
if (b7 < 0x80000000)
p = (b7<<1)/b4;
else
p = (b7/b4)<<1;
x1 = (p>>8) * (p>>8);
x1 = (x1 * 3038)>>16;
x2 = (-7357 * p)>>16;
p += (x1 + x2 + 3791)>>4;
return p;
}
// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
unsigned char data;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 1);
while(!Wire.available())
;
return Wire.receive();
}
// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
unsigned char msb, lsb;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 2);
while(Wire.available()<2)
;
msb = Wire.receive();
lsb = Wire.receive();
return (int) msb<<8 | lsb;
}
// Read the uncompensated temperature value
unsigned int bmp085ReadUT()
{
unsigned int ut;
// Write 0x2E into Register 0xF4
// This requests a temperature reading
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(0xF4);
Wire.send(0x2E);
Wire.endTransmission();
// Wait at least 4.5ms
delay(5);
// Read two bytes from registers 0xF6 and 0xF7
ut = bmp085ReadInt(0xF6);
return ut;
}
// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
unsigned char msb, lsb, xlsb;
unsigned long up = 0;
// Write 0x34+(OSS<<6) into register 0xF4
// Request a pressure reading w/ oversampling setting
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(0xF4);
Wire.send(0x34 + (OSS<<6));
Wire.endTransmission();
// Wait for conversion, delay time dependent on OSS
delay(2 + (3<<OSS));
// Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(0xF6);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 3);
// Wait for data to become available
while(Wire.available() < 3)
;
msb = Wire.receive();
lsb = Wire.receive();
xlsb = Wire.receive();
up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
return up;
}